build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.1-SNAPSHOT'
    }
}

apply plugin: 'forge'
apply plugin: 'scala'

version = "1.2.2"
group= "li.cil.oc" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "OpenComputers"

if (System.getenv("BUILD_NUMBER") != null)
    version += "-dev${System.getenv("BUILD_NUMBER")}"

minecraft {
    version = "1.7.2-10.12.0.1034"
    assetDir = "eclipse/assets"
}

processResources {
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

// because the normal default jar task has been modified to be obfuscated
task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
}

task apiJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'api'
//    exclude '**'
    include 'li/cil/oc/api/**'
}

artifacts {
    archives deobfJar
    archives apiJar
}